#! /bin/csh -f
# create_weekly

if ( $1 == "" ) then                   # input files
  set directory = ../Weekly
  set backdir = ../Backup
  set outdir = ../Data
else
  set directory = $1
  set backdir = $1"_Backup"
  set outdir = $1"_Data"
endif

set address = birk@xxx
set address = $address,amonson@xxx
set address = $address,persson@xxx
set address = $address,maginst@xxx

#set list = `ls $directory/fs*.dat`
set list = `ls $directory/fs*.dat | tail -1`  # last (newest) file
if ( $#list == 0 ) then
  # done in 'create_monthly.csh' set file = /tmp/fs2_alert ; rm -f $file
  # echo "No files from FourStar" > $file
  # mail -s "FourStar Alert" $address < $file
  exit
endif

foreach file ($list)
  set timestr = `fgrep LOCALTIME $file | awk '{print($2,$3,$4)}'`
  # LN2 levels
  set outfile = $outdir"/ln2levels7"
  set value1  = `fgrep LN2level1 $file | awk '{print($2)}'`
  set value2  = `fgrep LN2level2 $file | awk '{print($2)}'`
  echo $timestr $value1 $value2 >> $outfile
  # vacuum
  set outfile = $outdir"/vacuum7"
  set value1  = `fgrep Vacuum1 $file | awk '{print($2)}'`
  set value2  = `fgrep Vacuum2 $file | awk '{print($2)}'`
  echo $timestr $value1 $value2 >> $outfile
  # backend
  set outfile = $outdir"/backend7"
  set value1  = `fgrep TempCon1_Temp  $file | awk '{print($2)}'`
  set value2  = `fgrep TempCon1_Power $file | awk '{print($2)}'`
  set value3  = `fgrep TempMon1_Temp1 $file | awk '{print($2)}'`
  set value4  = `fgrep TempMon1_Temp2 $file | awk '{print($2)}'`
# set value4  = `fgrep TempMon1_Temp8 $file | awk '{print($2)}'`
  set value5  = `fgrep TempMon1_Temp7 $file | awk '{print($2)}'`
  echo $timestr $value1 $value2 $value3 $value4 $value5 >> $outfile
  # frontend
  set outfile = $outdir"/frontend7"
  set value1  = `fgrep TempCon2_Temp  $file | awk '{print($2)}'`
  set value2  = `fgrep TempCon2_Power $file | awk '{print($2)}'`
  set value3  = `fgrep TempMon2_Temp5 $file | awk '{print($2)}'`
  set value4  = `fgrep TempMon2_Temp6 $file | awk '{print($2)}'`
  set value5  = `fgrep TempMon2_Temp7 $file | awk '{print($2)}'`
  echo $timestr $value1 $value2 $value3 $value4 $value5 >> $outfile
  # wxinfo
  set outfile = $outdir"/wxinfo7"
  set value1  = `fgrep Temperature $file | awk '{print($2)}'`
  set value2  = `fgrep Dewpoint    $file | awk '{print($2)}'`
  set value3  = `fgrep Humidity    $file | awk '{print($2)}'`
  echo $timestr $value1 $value2 $value3 >> $outfile
  # LN2 fill mode
  set fillmode = `fgrep FillMode $file | awk '{printf($2)}'`
  # cleanup
  cp -fp $file $backdir
  # rm -f $file
end
rm -f $directory/fs*.dat

if (  $fillmode != 2.0000000 ) then
  set file = /tmp/fs2_alert ; rm -f $file
  echo "LN2 fill mode not in Automatic" > $file
  mail -s "FourStar Alert" $address < $file
endif

set list = ( ln2levels7 vacuum7 backend7 frontend7 wxinfo7 )
foreach file ($list)
  set name = $outdir"/"$file
  if { tail -174 $name > /tmp/fs2_junk7 } then  # 7*24+6
    mv -f /tmp/fs2_junk7 $name
  endif
end

gnuplot gnu-ln2levels7 >&/dev/null 
gnuplot gnu-vacuum7 >&/dev/null 
gnuplot gnu-backend7 >&/dev/null 
gnuplot gnu-frontend7 >&/dev/null 
gnuplot gnu-wxinfo7 >&/dev/null